// Race—p
val{
	steerl(default=180,min=150,max=210,step=5,disp=0)
	steerr(default=180,min=150,max=210,step=5,disp=0)

	brkfl(default=0,min=0,max=1000,step=10,disp=0)
	brkfr(default=0,min=0,max=1000,step=10,disp=0)
	brkrl(default=0,min=0,max=1000,step=10,disp=0)
	brkrr(default=0,min=0,max=1000,step=10,disp=0)

	pow  (default=0,min=-8000,max=300000,step=100000,disp=0)
	powfl(default=0,min=-8000,max=300000,step=100000,disp=0)
	powfr(default=0,min=-8000,max=300000,step=100000,disp=0)
	powrl(default=0,min=-8000,max=200000,step=100000,disp=0)
	powrr(default=0,min=-8000,max=200000,step=100000,disp=0)

	trqfl(default=1,min=0,max=1,step=0,disp=0)
	trqfr(default=1,min=0,max=1,step=0,disp=0)
	trqrl(default=1,min=0,max=1,step=0,disp=0)
	trqrr(default=1,min=0,max=1,step=0,disp=0)

	dmpf(default=0.3,disp=0)
	sprf(default=0.2,disp=0)
	dmpr(default=0.3,disp=0)
	sprr(default=0.2,disp=0)
	dmp(default=0.999,disp=0)
	spr(default=0.999,disp=0)
}
key{
//	2:steerl(step= 2),steerr(step=-2)
//	3:steerl(step=-2),steerr(step= 2)
	4:brkfl(step=50),brkfr(step=50),brkrl(step=50),brkrr(step=50)
	5:pow(step= 1200)
	6:pow(step=-1000)
}
body{
	core(){
	n:frame(name=c_0,spring=spr,damper=dmp){
		n:frame(spring=spr,damper=dmp){
			n:frame(spring=spr,damper=dmp){
				w:frame(spring=spr,damper=dmp){
					w:rudderf(angle=-steerl,spring=spr,damper=dmp,option=1){
						e:frame(angle=150,spring=sprf,damper=dmpf,option=1){
							e:frame(angle=-150,spring=sprf,damper=dmpf,option=1){
								e:wheel(power=powfl,brake=brkfl,angle=-95,option=1,effect=2,name=nwfl,spring=spr,damper=dmp){
								}
								e:chip(angle=-90,spring=spr,damper=dmp){
								}
							}
						}
					}
				}
				e:frame(spring=spr,damper=dmp){
					e:rudderf(angle=steerr,spring=spr,damper=dmp,option=1){
						w:frame(angle=150,spring=sprf,damper=dmpf,option=1){
							w:frame(angle=-150,spring=sprf,damper=dmpf,option=1){
								w:wheel(power=-powfr,brake=brkfr,angle=-95,option=1,effect=2,name=nwfr,spring=spr,damper=dmp){
								}
								w:chip(angle=-90,spring=spr,damper=dmp){
								}
							}
						}
					}
				}
				n:chip(angle=-160,spring=spr,damper=dmp){
					w:chip(spring=spr,damper=dmp){
					}
					e:chip(spring=spr,damper=dmp){
					}
				}
			}
		}
		s:frame(spring=spr,damper=dmp){
			s:frame(spring=spr,damper=dmp){
				w:frame(spring=spr,damper=dmp){
					w:frame(angle=150,spring=sprr,damper=dmpr,option=1){
						w:frame(angle=-150,spring=sprr,damper=dmpr,option=1){
							w:wheel(power=powrl,brake=brkrl,angle=-95,option=1,effect=3,name=nwrl,spring=spr,damper=dmp){
							}
							w:chip(angle=-90,spring=spr,damper=dmp){
							}
						}
					}
				}
				w:chip(angle=-90,spring=spr,damper=dmp){
					n:chip(angle=165){
					}
				}
				e:frame(spring=spr,damper=dmp){
					e:frame(angle=150,spring=sprr,damper=dmpr,option=1){
						e:frame(angle=-150,spring=sprr,damper=dmpr,option=1){
							e:wheel(power=-powrr,brake=brkrr,angle=-95,option=1,effect=3,name=nwrr,spring=spr,damper=dmp){
							}
							e:chip(angle=-90,spring=spr,damper=dmp){
							}
						}
					}
				}
				e:chip(angle=-90,spring=spr,damper=dmp){
					n:chip(angle=165){
					}
				}
				n:chip(angle=-160,spring=spr,damper=dmp){
					w:chip(spring=spr,damper=dmp){
					}
					e:chip(spring=spr,damper=dmp){
					}
				}
			}
		}
	}
	}
}
script{
	t=_split(1)

	vel=-_vz(c_0)
	wfl= _wy(nwfl)
	wfr=-_wy(nwfr)
	wrl= _wy(nwrl)
	wrr=-_wy(nwrr)

	if(vel>=0)&(vel<1){vel= 1}
	if(vel>-1)&(vel<0){vel=-1}

	rfl=wfl/vel
	rfr=wfr/vel
	rrl=wrl/vel
	rrr=wrr/vel

	// STEERING
	t=10/_pow(_abs(vel),0.5)
	if(_key(2)>0){
		steerl=steerl+t
		steerr=steerr-t
	}
	if(_key(3)>0){
		steerl=steerl-t
		steerr=steerr+t
	}

	// ABS
	if(_key(4)==0){goto trc}
	v=_abs(vel)*0.3
	if(rfl< 2){brkfl=brkfl*0.1}
	if(rfl>=2){brkfl=brkfl+v}
	if(rfr< 2){brkfr=brkfr*0.1}
	if(rfr>=2){brkfr=brkfr+v}
	if(rrl< 2){brkrl=brkrl*0.1}
	if(rrl>=2){brkrl=brkrl+v}
	if(rrr< 2){brkrr=brkrr*0.1}
	if(rrr>=2){brkrr=brkrr+v}
	brkfl=brkfl*0.5
	brkfr=brkfr*0.5

	// TRC
	label trc
	if(_vel(c_0)*3.6>50)&((rfl>5)|(rfr>5)|(rrl>5)|(rrr>5)){
		trqfl=trqfl*0.9
		trqfr=trqfr*0.9
		trqrl=trqrl*0.9
		trqrr=trqrr*0.9
		goto ayc
	}
	if(_vel(c_0)*3.6>50)&((rfl<-1)|(rfr<-1)|(rrl<-1)|(rrr<-1)){
		trqfl=0
		trqfr=0
		trqrl=0
		trqrr=0
		goto ayc
	}
	trqfl=trqfl+0.05
	trqfr=trqfr+0.05
	trqrl=trqrl+0.05
	trqrr=trqrr+0.05

	// AYC
	label ayc

	// POWCAL
	powfl=pow*trqfl*1.2
	powfr=pow*trqfr*1.2
	powrl=pow*trqrl
	powrr=pow*trqrr

	label fin
	print 0,"Chips=",_chips(),", Weight=",_weight(),", FPS=",_fps()
	print 1,"VEL=",vel,", Speed=",_vel(c_0)*3.6
	print 2,"WFL=",wfl,", WFR=",wfr,", WRL=",wrl,", WRR=",wrr
	print 3,"RFL=",rfl,", RFR=",rfr,", RRL=",rrl,", RRR=",rrr
	print 4,"X=",_x(c_0),", Y=",_y(c_0),", Z=",_z(c_0)
}