// Bike
//	 Record : 28.70 [4C46F8DC]

Val{
	pow(default=0,min=0,max=40000,step=0,disp=1)
	brkf(default=0,min=0,max=100,step=100,disp=1)
	brkr(default=0,min=0,max=100,step=100,disp=1)
	handle(default=90,min=45,max=135,step=1.5,disp=1)
	steer(default=0,min=-90,max=90,step=0,disp=1)
	spoil(default=6,min=6,max=18,step=0,disp=1)
	dmp(default=0.8,min=0,max=1,step=0,disp=0)
	spr(default=0.8,min=0,max=1,step=0,disp=0)
	sdmp(default=0.2,min=0,max=1,step=0,disp=0)
	sspr(default=0.15,min=0,max=1,step=0,disp=0)
//	stand1(default=0,min=0,max=110,step=5,disp=0)
//	stand2(default=57,min=0,max=180,step=6,disp=0)
}
Key{
	2:handle(step=-1.5)
	3:handle(step=1.5)
	4:brkf(step=9),brkr(step=10)
}
Body{
	core(){
		n:trimf(angle=handle,spring=spr,damper=dmp){
			n:rudderf(angle=-135,spring=sspr,damper=sdmp){
				s:trimf(angle=steer,spring=sspr,damper=sdmp){
					s:wheel(name=whf,brake=brkf,option=2,effect=2,spring=spr,damper=dmp){
					}
				}
			}
			s:frame(spring=spr,damper=dmp){
				s:rudderf(angle=-45,spring=sspr,damper=sdmp){
					s:wheel(name=whr,brake=brkr,option=2,effect=2,spring=sspr,damper=sdmp,power=pow){
					}
				}
//				e:frame(angle=stand1,spring=spr,damper=dmp){
//					e:frame(angle=stand2,spring=spr,damper=dmp){
//					}
//				}
//				e:frame(angle=-stand1,spring=spr,damper=dmp){
//					e:frame(angle=-stand2,spring=spr,damper=dmp){
//					}
//				}
			}
		}
		n:chip(angle=spoil){
		}
	}
}
Script{
	vel=-_vz(0)
	ez=_ez(0)
	wz=_wz(0)
	wyf=_wy(whf)
	wyr=_wy(whr)
	hhf=_h(whf)
	hhr=_h(whr)
	v=vel
	if(v>-1)&(v<0){v=-1}
	if(v>=0)&(v<1){v= 1}
	raf=wyf/v
	rar=wyr/v

	// ハンドル制御
	if(_abs(vel)<1){
		handle=(handle-90)*0.9+90
		steer=steer*0.9
		goto skip
	}
	m=32
	n=1
	h=3
	k=1
	s=_todeg(ez)*n*m/(_abs(vel)+m)-steer
	s=h*(1-2/(1+_exp(s/k)))
	steer=steer+s
	label skip

	// スポイラ
	spoil=_abs(handle-90)*1.25+(hhf-hhr)*150

	// アクセル
//	if(_key(5)==0){pow=0}
	if(_key(5)>0){pow=pow+50000}
	pow=pow+50000	// Auto Accel
	if(pow>vel*420+5000){pow=vel*420+5000}
	if(hhr>=0){pow=pow*(hhr-0.4)/0.2}
	if(hhr>=1)|(hhr<0){
		pow=0
		steer=steer*0.9
	}

	// ブレーキ
	if(brkf>0)&(raf<1.5){brkf=0}
	if(brkr>0)&(rar<1.5){brkr=0}

	// スタンド収める
//	if(vel>5){
//		stand1=stand1+2
//		stand2=stand2+2
//	}

	print 0,"Chips=",_chips(),", Weight=",_weight(),", FPS=",_fps()
	print 1,"VEL=",vel,", Speed=",_vel(0)*3.6
	print 2,"Ez=",ez," (",_todeg(ez),")"
	print 3,"WyF=",wyf,", WyR=",wyr
	print 4,"RaF=",raf,", RaR=",rar
	print 5,"H=",hhr
	print 6,"X=",_x(0),", Y=",_y(0),", Z=",_z(0)
}