• Visual Basic の Shell コマンドを使用する方法。この方法を実行すると、
  新規プロセスを生成し、生成されたプロセスのプロセス ID を返します。
  このときプロセス ハンドルを取得する必要があります。プロセス ハンドルは、
   OpenProcess API 呼び出しで取得することができます。
• プロセス オブジェクトとメイン スレッド オブジェクトを同時に生成する
  CreateProcess API 関数を使用する方法。プロセスとイニシャル スレッドは、
  生成時に 32 ビットの識別子 (ID) が割り当てられます。この ID は、
  それぞれのオブジェクト (プロセスまたはスレッド) が破棄されるまで有効です。
  この 32 ビット ID は、システム内でオブジェクトを一意に識別するために使われます。
  新しく生成されたプロセスとスレッドには、フル アクセス権を持つハンドルが
  それぞれに生成されます。これら 4 つの値は、CreateProcess に渡される
  ROCESS_INFORMATION 構造体に返されます。

  重要: ハンドルのクローズは大変重要です。ハンドルのクローズがきちんと行われて
        いないと、Windows NT エグゼクティブ オブジェクトの一部が破棄されないま
        ま残ってしまうため、メモリ リークを引き起こす可能性があります。

手順

1. Visual Basic で新規プロジェクトを作成します。デフォルトでは Form1 が作成されます。
   フォームにコマンド ボタンを２個配置します。

   　

2. Form1 の General Declarations セクションに次のコードを追加します。

     Option Explicit
     Private Type PROCESS_INFORMATION
        hProcess    As Long
        hThread     As Long
        dwProcessId As Long
        dwThreadId  As Long
     End Type
     Private Type STARTUPINFO
        cb              As Long
        lpReserved      As String
        lpDesktop       As String
        lpTitle         As String
        dwX             As Long
        dwY             As Long
        dwXSize         As Long
        dwYSize         As Long
        dwXCountChars   As Long
        dwYCountChars   As Long
        dwFillAttribute As Long
        dwFlags         As Long
        wShowWindow     As Integer
        cbReserved2     As Integer
        lpReserved2     As Long
        hStdInput       As Long
        hStdOutput      As Long
        hStdError       As Long
     End Type
   
     Private Declare Function CreateProcess Lib "kernel32" _
       Alias "CreateProcessA" ( _
       ByVal lpApplicationName As String, _
       ByVal lpCommandLine As String, _
       lpProcessAttributes As Any, _
       lpThreadAttributes As Any, _
       ByVal bInheritHandles As Long, _
       ByVal dwCreationFlags As Long, _
       lpEnvironment As Any, _
       ByVal lpCurrentDriectory As String, _
       lpStartupInfo As STARTUPINFO, _
       lpProcessInformation As PROCESS_INFORMATION _
       ) As Long
   
     Private Declare Function OpenProcess Lib "kernel32.dll" ( _
       ByVal dwAccess As Long, _
       ByVal fInherit As Integer, _
       ByVal hObject As Long _
       ) As Long
   
     Private Declare Function TerminateProcess Lib "kernel32" ( _
       ByVal hProcess As Long, _
       ByVal uExitCode As Long _
       ) As Long
   
     Private Declare Function CloseHandle Lib "kernel32" ( _
       ByVal hObject As Long _
       ) As Long
   
     Const SYNCHRONIZE = 1048576
     Const NORMAL_PRIORITY_CLASS = &H20&

3. Command1_Click イベントに次のコードを追加します。

     Dim pInfo As PROCESS_INFORMATION
     Dim sInfo As STARTUPINFO
     Dim ret   As Long
   
     sInfo.cb = LenB(sInfo)
     ret = CreateProcess(vbNullString, _
                        "calc.exe", _
                        ByVal 0&, _
                        ByVal 0&, _
                        1&, _
                        NORMAL_PRIORITY_CLASS, _
                        ByVal 0&, _
                        vbNullString, _
                        sInfo, _
                        pInfo _
     )
   
     MsgBox "[電卓] を終了させます"
   
     TerminateProcess pInfo.hProcess, 0&
     CloseHandle pInfo.hThread
     CloseHandle pInfo.hProcess

4. Command2_Click イベントに次のコードを追加します。

     Dim ProcessID     As Long
     Dim ProcessHandle As Long
     ProcessID = Shell("calc.exe", vbNormalFocus)
     ProcessHandle = OpenProcess(SYNCHRONIZE, True, ProcessID)
   
     MsgBox "[電卓] を終了させます"
   
     TerminateProcess ProcessHandle, 0&
     CloseHandle ProcessHandle

5. Ctrl + F5 キーを押してプログラムを実行します。Command1 をクリックします。
   メッセージと同時に Windows の [電卓] が起動します。
   メッセージ ボックスの [OK] をクリックすると [電卓] が終了します。
   Shell コマンドと OpenProcess を使った場合の動作を確認したい場合は、
   Command2 クリックします。